          SUBROUTINE (ROID,GEN,STATUS,PRT.ON,DRPT)
** Version# 34.0001[77] - 11/19/2014 - 09:42am - TSMITH - eclipse
*** V34.0001 Change - Custom Coding . - 11/19/2014 - TSMITH - eclipse

*** Subroutine : RENTAL.PRINT.ORDER
*-------------------------------------------------------------------------*
*** This routine performs the actual act of printing (or faxing) the
*** current rental agreement
*-------------------------------------------------------------------------*
*** Parameters:
*** ROID   - Rental ID                                                [IN]
*** GEN    - Generation ID                                            [IN]
*** STATUS - Print Status                                             (IN)
*** PRT.ON -                                                          (IN)
*** DRPT   -                                                          (IN)
*-------------------------------------------------------------------------*
          DIM PSTYL(10)
          OPEN 'PRINT.STYLES' TO PSTYLFILE ELSE RETURN

          SV.LOC = LOCATION
          PG.LGTH   = 60
          FT.LGTH   = 0
          BOD.LINES = 36
          IF DRPT<29> THEN BOD.LINES -= 1
          IF NOT(PHANTOM.PROC) AND NOT(PRT.ON) THEN
             WINDOW 15,8,50,5
             IF DRPT<29> THEN
                PRINT @(0,1):'Faxing .... ':ROID
             END ELSE
                PRINT @(0,1):'Printing .... ':ROID
             END
          END

          MATREAD LED FROM RLEDFILE,ROID ELSE GOTO FINISH

          BR      = LED(2)<1,GEN,1>
          GEN     = 1
          QSIGN   = -1
          SHIP.BR = LED(2)<1,GEN,2>
          READV BR.EN FROM TERRFILE,BR,4 ELSE BR.EN = ''
          READ CUS.BR FROM CUSFILE,BR.EN ELSE CUS.BR=''
          PRC.PHONES = CUS.BR<17>
          PRC.BR.PHONES = PRC.PHONES<1,1>
          IF PRC.PHONES<1,2> THEN
             PRC.BR.PHONES := ' Fax ':PRC.PHONES<1,2>
          END
          READV BR.EN FROM TERRFILE,SHIP.BR,4 ELSE BR.EN = ''
          READ CUS.BR FROM CUSFILE,BR.EN ELSE CUS.BR=''
          BR.ADDR = CUS.BR<1>
          IF CUS.BR<2,1> THEN BR.ADDR<-1> = CUS.BR<2,1>
          IF CUS.BR<2,2> THEN BR.ADDR<-1> = CUS.BR<2,2>
          BR.ADDR<-1> = CUS.BR<3>:' ':CUS.BR<4>:' ':CUS.BR<5>
          IF CUS.BR<17,2> = '' THEN FAX.PHONE = '' ELSE FAX.PHONE = '  Fax ':CUS.BR<17,2>
          BR.ADDR<-1> = CUS.BR<17,1>:FAX.PHONE

          BT.CN  = LED(1)<1,GEN>
          ST.CN  = LED(5)<1,GEN>
          GET.CUS BR,BT.CN,ST.CN,QSIGN
          PRT.LDIDS = RAISE(LED(48)<1,GEN>)
          CONVERT VM TO AM IN PRT.LDIDS

          IF NOT(PRT.ON) THEN
             PRINTER.ON "RENTAL.ORDER",RPT.DFLT=DRPT
          END

          GOSUB INIT

          LDID.CT = DCOUNT(PRT.LDIDS,AM)
          FOR LD.NO = 1 TO LDID.CT
          LDID   = PRT.LDIDS<LD.NO>
          GOSUB PRT.LINE
          NEXT LD.NO

          GOSUB PRINT.TOTALS
          GOSUB ADD.FTR

          PGS = INT((BLINE + BOD.LINES-1)/BOD.LINES)

          GOSUB HEADER
          GOSUB PRTBOD
          GOSUB FFEED

          IF NOT(PRT.ON) THEN
             PRINTER.OFF
          END

          GOTO FINISH
*-------------------------------------------------------------------------*
INIT:     PAGE    = 0
          TSPACES = 69
          ORD.AMT = 0
          LINE.CT = 0
          SSPC    = 11
          BOD     = ''
          BLINE   = 0
          ORD.ID  = ROID
          BEGIN CASE
          CASE STATUS = 'P'
             FT.LGTH += 9
             DOC.ID   = 'Rental Pickup'
             DOC.TYPE = 'P'
          CASE STATUS = 'C'
             FT.LGTH += 9
             DOC.ID   = 'Rental Close'
             DOC.TYPE = 'C'
          CASE OTHERWISE
             FT.LGTH += 9
             DOC.TYPE = 'A'
             DOC.ID   = 'Rental Agreement'
          END CASE

                    SLPI   = CHAR(27):"&l6D"
          ELPI   = CHAR(27):"&l8D"

          *** Set up some variables to use for setting text fonts...
          SMALL      = CHAR(27):'(8U'
          SMALL     := CHAR(27):'(s0p16.67h8.5v0s0b0T'
          MED        = CHAR(27):"(8U":CHAR(27):'(s0p12h0s3b3T'
          SUP.SMALL  = CHAR(27):"(8U":CHAR(27):'(s0p20h0s0b0T'
          NORM       = CHAR(27):'(8U'
          NORM      := CHAR(27):'(s0p10h12v0s0b3T'
          NORM.BOLD  = CHAR(27):'(8U'
          NORM.BOLD := CHAR(27):'(s0p10h12v0s1b3T'
          LARGE      = CHAR(27):'(8U'
          LARGE     := CHAR(27):'(s1p10h14v0s3b3T'
          XLARGE     = CHAR(27):'(8U'
          XLARGE    := CHAR(27):'(s0p8h8v0s3b3T'


          PSTYLE.OVRD=''

* Get Print style record
          BEGIN CASE
          CASE PSTYLE.OVRD#''
             STYLE.ID = PSTYLE.OVRD
          CASE LED(77)
             STYLE.ID = LED(77)<1,GEN>
          CASE CUSS(42)
             STYLE.ID = CUSS(42)
          CASE CUS(42)
             STYLE.ID = CUS(42)
          CASE OTHERWISE
             STYLE.ID = 'NET'
          END CASE

           GOSUB GET.PSTYLE

                DOC.FORM.SPEC = ''
          READ DOC.FORM.REC FROM CTRLFILE,'RENTAL' THEN
             GOSUB CNVRT.FORM
          END ELSE
             DOC.FORM.REC = ''
          END



          *COLUMN.HEADING = "Location   Product Description                 Check In ": TIME.ZONE$ "L#3" :" Period   Ext Price"
          COLUMN.HEADING = ''
          CUS.PO   = LED(13)<1,GEN>
          REL.NO   = LED(65)<1,GEN>
          CHK.OUT  = OCONV(LED(9)<1,GEN,1>,'D2/'):' ':OCONV(LED(9)<1,GEN,2>,'MTH')

          SALESMAN = LED(72)<1,GEN>
          READV SALESMAN FROM INIFILE,SALESMAN,3 ELSE NULL
          WRITER   = LED(73)<1,GEN>
          READV WRITER FROM INIFILE,WRITER,3 ELSE NULL
          ORD.BY   =  LED(68)<1,GEN>
          SHIP.VIA = LED(70)<1,GEN>
          PHONE.NO = CUS(17)<1,1>
          TERMS.ID = LED(29)<1,GEN>
          READV TERMS.DESC FROM TERMSFILE,TERMS.ID,1 ELSE TERMS.DESC=''
          SHIP.ADDR      = CUSS(1)
          BILL.ADDR      = CUS(1)
          SHIP.ADDR<-1>  = LED(78)<1,GEN,1>
          IF LED(78)<1,GEN,2> # '' THEN SHIP.ADDR<-1>= LED(78)<1,GEN,2>
          SHIP.ADDR<-1>= LED(78)<1,GEN,3>"L#20":LED(75)<1,GEN>"L#10"
          IF CUS(2)<1,1> # '' THEN BILL.ADDR<-1> = CUS(2)<1,1>
          IF CUS(2)<1,2> # '' THEN BILL.ADDR<-1> = CUS(2)<1,2>
          BILL.ADDR<-1> = (CUS(3):',')"L#16":CUS(4)"L#4":CUS(5)"L#14"
          BILL.ADDR<-1> = PHONE.NO

          SHP.INST = LED(74)<1,GEN>

          IF SHP.INST#'' THEN
             BLINE += 1
             BOD<BLINE> = SPACE(SSPC):'***** Shipping Instructions ******'
             CT = DCOUNT(SHP.INST,SVM)
             FOR JJ=1 TO CT
             BLINE += 1
             BOD<BLINE> = SPACE(SSPC):'* ':SHP.INST<1,1,JJ>"L#30":' *'
             NEXT JJ
             BLINE += 1
             BOD<BLINE> = SPACE(SSPC):STR('*',34)
          END
          PRT.TIME =  TIMEDATE()
          BO.PNS   = ''
          RETURN
*-------------------------------------------------------------------------*
HEADER:   PAGE += 1
*** Skip the preprinted header on the form
          FOR XLN = 1 TO 10
          PRINT
          NEXT XLN

          *** Print the macro
          MACRO.ID = 'PICK~':STYLE.ID
          GOSUB SET.MACRO

           *** Print the logo
          PRINT CHAR(27):"*p25y*p50X":
          PTR.MACRO.PRINT ERR.MSG, 'PICK', DRPT
          PRINT CHAR(27):"*p0Y":
          PRINT NORM:SLPI:
          PRINT ; PRINT
          PRINT

          PRINT SPACE(52):XLARGE:"** ":DOC.ID:" **":NORM
          PRINT SPACE(52):'Page # : ':PAGE:' of ':PGS


          PRINT '' "L#1":LARGE:'GP SUPPLY COMPANY':NORM
          PRINT '' "L#1":LARGE:'501 E WASHINGTON STREET':NORM
          PRINT '' "L#1":LARGE:'GREENSBORO, NC 27401':NORM
          PRINT '' "L#1":LARGE:'336-274-7615  FAX 336-370-4715':NORM
          PRINT
          PRINT



          *PRINT ("** ":DOC.ID:" **") "R#46":




          PRINT '    Bill To:'       "L#40":
          PRINT '    Ship To:'
          FOR JJ=1 TO 5
             PRINT SPACE(4): BILL.ADDR<JJ>'L#40': SHIP.ADDR<JJ>'L#35'
          NEXT JJ
          PRINT

*         PRINT STR('_',80)
     * Header additional data Line #1
        *  PRINT 'Ordered by' "L#15 ":
        *  PRINT 'Check Out'  "L#9 ":
        *  PRINT TIME.ZONE$   "L#3    ":
        *  PRINT 'P/O #'      "L#20 ":
        *  PRINT 'Ship Via'   "L#16 ":
        *  PRINT 'Order # '
PRINT
PRINT
PRINT
          PRINT ' ':ORD.BY      "L#14 ":
          PRINT CHK.OUT        "L#16 ":
          PRINT CUS.PO         "L#20 ":
          PRINT SHIP.VIA       "L#16 ":
          PRINT ORD.ID
          PRINT
*         PRINT STR('_',80)

        *  PRINT 'Writer'          "L#15 ":
        *  PRINT 'Salesperson'     "L#16 ":
        *  PRINT 'Release #'       "L#37 ":
        * PRINT 'Customer#'
     PRINT
          PRINT ' ':WRITER            "L#14 ":
          PRINT SALESMAN          "L#16 ":
          PRINT REL.NO            "L#20 ":SPACE(17):
          PRINT LED(5)<1,GEN>     "L#9"

 *        PRINT STR('_',80)

          PRINT COLUMN.HEADING
          RETURN
*-------------------------------------------------------------------------*
PRTBOD:   PLINE = 1
          LINEX = 0
          LOOP
          LINEX += 1
          IF LINEX > BLINE THEN EXIT
              IF PLINE > BOD.LINES THEN GOSUB TOP; PLINE=1
          PRINT BOD<LINEX>
          PLINE += 1
          REPEAT

          FOR X = PLINE TO BOD.LINES
             PRINT
          NEXT X

          GOSUB FFEED

          RETURN
*-------------------------------------------------------------------------*
TOP:    *
          PRINT "     *** Continued on Next Page ***"
          GOSUB FFEED
          GOSUB HEADER
          RETURN
*-------------------------------------------------------------------------*
PRINT.TOTALS: *
          GOSUB PRINT.TOTAL.LINE
          TOTAL.COMMENT = 'Total Amount'
          TOTAL.AMT     = OCONV(ORD.AMT,'MR9')
          GOSUB PRINT.TOTAL

          RETURN
*-------------------------------------------------------------------------*
PRINT.TOTAL: *
          PRT.STR = SPACE(TSPACES-LEN(TOTAL.COMMENT)-13)
          PRT.STR = PRT.STR:'  ':TOTAL.COMMENT:''"L#10"
          PRT.STR = PRT.STR:TOTAL.AMT "R2#11"
          BLINE += 1
          BOD<BLINE> = PRT.STR
          RETURN
*-------------------------------------------------------------------------*
PRINT.TOTAL.LINE: *
          PRT.STR = SPACE(TSPACES):STR('-',10)
          BLINE += 1
          BOD<BLINE> = PRT.STR
          RETURN
*-------------------------------------------------------------------------*
PRT.LINE: LD.GET LDID
          PN = LD(1)
          BEGIN CASE
          CASE NUM(PN)
             GOSUB PRT.PN
          CASE PN='C'
             SAVE.COMMENT = LD(3)
             DESC = SAVE.COMMENT
             SAVE.COMMENT = ''
             GOSUB PRT.XDESC
          END CASE
          RETURN
*-------------------------------------------------------------------------*
PRT.PN:   *
          GET.ALL.PRD LED(2)<1,GEN,2>,PN,QSIGN,GROUP
          OE.DESC.GET DESC
          DESC<1,-1>  = "Inspected By: ":STR("_",19)
          DESC<1,-1>  = "Checked Out : ":CHK.OUT "L#17 "

          IF LD(32) # "" THEN
             DESC<1,-1> = "Rental ID   : R":LD(32)
             READV RENTAL.DESC FROM RENTFILE,LD(32),6 THEN
                DESC<1,-1> = RENTAL.DESC
             END
          END


          IF LD(32) # "" THEN
          READV RENTAL.SERIAL FROM RENTFILE,LD(32),5 THEN
                DESC<1,-1> = "Serial No.  : ":RENTAL.SERIAL
          END
          END

*** Calculate the extended rate and periods
          LDT.IN   = LD(13)<1,1>
          LTM.IN   = LD(13)<1,2>
          LDT.OUT  = LD(14)<1,1>
          LTM.OUT  = LD(14)<1,2>
          RPERIOD  = LD(84)<1,1>
          UNITS    = ""
          IF LD(9)<1> # "" THEN
             OVRD.AMT = ICONV(OCONV(LD(8)<1>,'MR9'),"MR3")
          END ELSE
             OVRD.AMT = ""
          END
          RENTAL.CALC.AMT ROID,LED(28)<1,GEN>,LD(1),TOTAL,LDT.OUT,LTM.OUT,LDT.IN,LTM.IN,XINFO,,RPERIOD,LED(22)<1,GEN>,OVRD.AMT

          UCT   = DCOUNT(XINFO<1>,VM)
          FOR ULN = 1 TO UCT
          UNITS = UNITS:XINFO<1,ULN>:XINFO<2,ULN>:" "
          NEXT ULN

          CHK.IN  = OCONV(LDT.IN,'D0/'):' ':OCONV(LTM.IN,'MTH')
          CHK.OUT  = OCONV(LDT.OUT,'D0/'):' ':OCONV(LTM.OUT,'MTH')
          LOCA    = FIELD(FIELD(LD(7)<1>,'~',2),'^',1)

          PRT.STR = ' ':LOCA "L#9 ":DESC<1,1>            "L#35 "
          PRT.STR = PRT.STR:CHK.IN "L#12 ":UNITS "L#8 "
          PRT.STR = PRT.STR:OCONV(TOTAL,'MR9')   "R2#10"
          ORD.AMT += TOTAL

          BLINE += 1
          BOD<BLINE> = PRT.STR
          DESC       = DELETE(DESC,1,1)
          GOSUB PRT.XDESC

          RETURN
*-------------------------------------------------------------------------*
PRT.XDESC: *
          DESC.CT = DCOUNT(DESC,VM)
          FOR DLN = 1 TO DESC.CT
          PRT.STR = SPACE(SSPC):DESC<1,DLN>
          IF TRIM(PRT.STR) THEN
             BLINE += 1
             BOD<BLINE> = PRT.STR
          END
          NEXT DLN
          RETURN
*-------------------------------------------------------------------------*
ADD.FTR:  *
          IF FT.LGTH = 0 THEN RETURN
          PGS = INT((BLINE+BOD.LINES-1)/BOD.LINES)
          LAST.PG = PGS*BOD.LINES - BLINE
          IF LAST.PG >= FT.LGTH THEN
             ADD.LINES = LAST.PG - FT.LGTH
          END ELSE
             ADD.LINES = BOD.LINES + LAST.PG - FT.LGTH
          END
          FOR X = 1 TO ADD.LINES
             BLINE += 1
             BOD<BLINE> = ''
          NEXT X
          *BLINE += 1
          *BOD<BLINE> = "Deposit : $":STR("_",16):" CC":STR("_",12):" Cash":STR("_",12):" Check":STR("_",12)
          *BLINE += 1
          *BOD<BLINE> = ""
          BLINE += 1
          BOD<BLINE> = "Customer Out":STR("_",20):" Print Name":STR("_",20):" Date":STR("_",9)
          BLINE += 1
          BOD<BLINE> = ""
          BLINE += 1
          BOD<BLINE> = "Customer In ":STR("_",20):" Print Name":STR("_",20):" Date":STR("_",9)
          *BLINE += 1
          *BOD<BLINE> = STR("=",79)
          *BLINE += 1
          *BOD<BLINE> = "Picked By":STR("_",23):" Time/Date Out":STR("_",25)
          *BLINE += 1
          *BOD<BLINE> = ""
          *BLINE += 1
          *BOD<BLINE> = "Rec'd By ":STR("_",23):" Time/Date In ":STR("_",25)

          RETURN
*-------------------------------------------------------------------------*
CNVRT.FORM: * Convert the values we picked up from our Form overlay
            * Control Record AND from the Print Style Id we're using,
            * that was set up in Print Style Maintenance...

*** Get data out from the Form Overlay Control Record we're using...

          *** We should find this string in the Row where our Invoice's
          *** data columns were set up...
          FINDSTR '@PRINT.STYLE' IN DOC.FORM.REC SETTING AMC THEN
             *** Get the Print Style Width....
             FORM.STYLE.WIDTH = FIELD(DOC.FORM.REC<AMC>,',',2)
             *** Initialize our Total Width to be the Print Style Width...
             TOTAL.WIDTH      = FORM.STYLE.WIDTH

             TAMC = AMC - 1
             *** Go through each data column that's been set up in the
             *** current row...
             LOOP
             UNTIL DOC.FORM.REC<TAMC>[1,1] # '"' DO
                *** Add the width from each column to our Total Width...
                TOTAL.WIDTH += FIELD(DOC.FORM.REC<TAMC>,',',2)
                TAMC -= 1
             REPEAT

             *** Set our Start Column, where we'll be printing the values
             *** determined by our print style Id...
             COL.START    = TOTAL.WIDTH - FORM.STYLE.WIDTH
             DEL DOC.FORM.REC<AMC>

*** Now we'll go through the columns that were set up for the Print
*** Style Id we're using (set up in Print Style Maintenance)...

             STYLE.WIDTH  = 0
             WIDTH.INSERT = ''

             FOR CC = 1 TO COL.CT
                TWIDTH           = FIELD(COL.FRMTS<1,CC>,'#',2)
                WIDTH.INSERT<CC> = TWIDTH
                STYLE.WIDTH     += TWIDTH
             NEXT CC

             BEGIN CASE
             *** If the actual width of our Print Style Id columns is less
             *** than the width that our Form Overlay Control Record
             *** stated that it needed to be...
             CASE STYLE.WIDTH < FORM.STYLE.WIDTH
                CC = COL.CT
                LOOP
                UNTIL STYLE.WIDTH >= FORM.STYLE.WIDTH DO
                   *** Increase a columns width...
                   WIDTH.INSERT<CC> += 1
                   NEW.FRMT  = FIELD(COL.FRMTS<1,CC>,'#',1):'#'
                   NEW.FRMT := WIDTH.INSERT<CC>
                   COL.FRMTS<1,CC> = NEW.FRMT

                   CC -= 1
                   *** If we've already increased each columns width
                   *** once, start with the first one again...
                   IF CC < 1 THEN CC = COL.CT
                   STYLE.WIDTH += 1
                REPEAT
             *** If the actual width of our Print Style Id columns is
             *** greater than the width that our Form Overlay Control
             *** Record stated that it needed to be...
             CASE STYLE.WIDTH > FORM.STYLE.WIDTH
                CC = 1
                LOOP
                UNTIL STYLE.WIDTH <= FORM.STYLE.WIDTH DO
                   *** Decrease a columns width...
                   WIDTH.INSERT<CC> -= 1
                   NEW.FRMT  = FIELD(COL.FRMTS<1,CC>,'#',1):'#'
                   NEW.FRMT := WIDTH.INSERT<CC>
                   COL.FRMTS<1,CC> = NEW.FRMT

                   CC += 1
                   *** If we've already decreased each columns width
                   *** once, start with the first one again...
                   IF CC > COL.CT THEN CC = 1
                   STYLE.WIDTH -= 1
                REPEAT
             END CASE

             FOR CC = 1 TO COL.CT
                TINSERT  = '"':COL.HEADS<1,CC>:'",'
                TINSERT := WIDTH.INSERT<CC>

                INS TINSERT BEFORE DOC.FORM.REC<AMC+CC-1>
             NEXT CC

             FTR.TEXT.LGTH = 79-WIDTH.INSERT<COL.CT>
             FTR.FMT       = 'R2#':WIDTH.INSERT<COL.CT>
          END

          RETURN
*-------------------------------------------------------------------------*
GET.PSTYLE: *
          * Get Print style record
          MATREAD PSTYL FROM PSTYLFILE,STYLE.ID ELSE
             MATREAD PSTYL FROM PSTYLFILE,'DEFAULT' ELSE
                MAT PSTYL = ''
                PSTYL(3) = 69
                PSTYL(4) = 'R2#10'
                PSTYL(5) = 1
                PSTYL(6) = 1
                PSTYL(7) = 'Net Price'
             END
          END
          COL.START = PSTYL(3)
          COL.FRMTS = PSTYL(4)
          COL.BASIS = PSTYL(5)
          COL.EXTDS = PSTYL(6)
          COL.HEADS = PSTYL(7)
          ALT.DESC  = PSTYL(8)
          COL.CT    = DCOUNT(COL.BASIS,VM)
          COL.TOTAL = ''
          SUB.TOTAL = ''
          SUBT.SW   = NO

          RETURN

*-------------------------------------------------------------------------*
SET.MACRO: *** Print macro or create if necessary

          MACRO.OK = ''

          *** Check to see if this macro is already loaded
          PTR.MACRO.ACTIVE MACRO.ID,PRT.SEQ

          *** If a sequence is returned, use to print macro immediately
          IF PRT.SEQ THEN GOTO PRT.MACRO

          *** Begin saving macro (suspend physical printing)
          PTR.MACRO.SAVE.ON MACRO.ID,MACRO.OK

          *** 'Print' the overlay - this does NOT physically print,
          *** anything between SAVE statements is only saved to macro
          DOC.FORM.CONVERT DOC.FORM.REC,DOC.FORM.SPEC
          DOC.FORM.PRINT DOC.FORM.SPEC,"1"
          GOSUB DRAWSHADING

          *** Stop saving macro (resume physical printing)
          PTR.MACRO.SAVE.OFF MACRO.ID,MACRO.OK,PRT.SEQ

PRT.MACRO: *** Print the macro with saved or newly created sequence

          IF PRT.SEQ THEN
             *** For each !, print CHAR(27) and the following characters
             CONVERT '!' TO AM IN PRT.SEQ
             ESC.CT = DCOUNT(PRT.SEQ,AM)
             FOR XX = 2 TO ESC.CT
                PRINT CHAR(27):PRT.SEQ<XX>:
             NEXT XX
             PRINT
          END

          RETURN
*-------------------------------------------------------------------------*
DRAWSHADING: *** Draw shaded boxes to fill in headers

          PERC = 11   ;* Shade at 11%
          REST = 100  ;* Restore to 100%
          HGHT = 1    ;* All boxes are 1 char height

*          FORMS.PRINT.SHADE PERC,1621, 190,2.5,HGHT,REST  ;* Inv Dt/Number
*          FORMS.PRINT.SHADE PERC,2101, 340,0.9,HGHT,REST  ;* Page Number
          FORMS.PRINT.SHADE PERC,   0, 910,7.9,HGHT,REST  ;* 1st full line
          FORMS.PRINT.SHADE PERC,   0,1060,7.9,HGHT,REST  ;* 2nd full line
          FORMS.PRINT.SHADE PERC,   0,1210,7.9,HGHT,REST  ;* 3rd full line

          RETURN
*-------------------------------------------------------------------------*
FFEED:    *

          *** Print barcode.
          PRINT CHAR(27):"*p1750x*p3175Y":
          UT.PRINT.BARCODE ERR.CODE,'CODE128',150,25,7,ORD.ID

          *PRINT CHAR(12):

          RETURN
*-------------------------------------------------------------------------*
FINISH:   IF NOT(PHANTOM.PROC) AND NOT(PRT.ON) THEN
             WINDOW.CLOSE
          END
          LOCATION = SV.LOC
          RETURN
!TSMITH~11/19/14~09:42
